Option Explicit
Dim wshshell,fso,i,Fnct
Dim strPath,strSystemFolder,strWinFolder,strTempFolder
'----------------------------- Objekte erzeugen --------------------------------
i = 0
On Error Resume Next
Do 
	err.Clear
	i = i+1
	Set wshshell = CreateObject("WScript.Shell")
	Set fso = CreateObject("Scripting.FileSystemObject")
	Set Fnct = CreateObject("Install.Functions")
	WScript.Sleep 1000
Loop Until Err.Number = 0 OR i > 30

If Err.Number <> 0 Then
	WScript.Quit
End If

On Error Goto 0

'--------------------------- Standardpfade -------------------------------------
strPath = GetCurrentPath()
strSystemFolder = fso.GetSpecialFolder(1) & "\"
strWinFolder = fso.GetSpecialFolder(0) & "\"
strTempFolder = fso.GetSpecialFolder(2) & "\"


'------------------------------ Main -------------------------------------------
Dim strServicepackDir,Key,strMainVolume
strMainVolume = ExpandPath("%MAIN_VOLUME%","c:\")
strServicepackDir = ExpandPath("%SERVICEPACKDIR%",strMainVolume & "Servicepacks")

Call wshshell.Run(strPath & "Warning.vbs")
Call wshshell.Run(strPath & "PrepareStart2.vbs",1,True)
Call wshshell.Run(strPath & "Install2.vbs",1,True)
Call wshshell.Run(strPath & "PrepareRestart2.vbs",1,True)

If Not fso.FileExists(strServicepackDir & "\Start.vbs") Then
	Call wshshell.Run(strPath & "CopyFileCD.vbs " & strPath & _
						"Insert3.vbs " & strTempFolder,_
						1,True)
	Call wshshell.Run(strPath & "CopyFileCD.vbs " & strPath & _
						"ExitIns3.vbs " & strTempFolder,_
						1,True)
	
	key = "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\VbStart"
	wshshell.RegWrite key,"Wscript.exe " & strTempFolder &"Insert3.vbs"
End If

Call wshshell.Run(strPath & "CD2EndDlg.vbs")
do
	WScript.Sleep(5000)
loop until Not wshshell.AppActivate("End")
	

Call Fnct.ExitWindows(2)
'------------------------------- Funktionen ------------------------------------
Function GetCurrentPath()
    Dim l_strScriptName
    Dim l_strTemp

    l_strScriptName = WScript.ScriptFullName
    l_strTemp = WScript.ScriptName
    GetCurrentPath = Left(l_strScriptName, Len(l_strScriptName) - Len(l_strTemp))
End Function

Function ExpandPath(p_strEnvironment,p_strDefault)
	Dim l_strTemp
	l_strTemp = wshshell.ExpandEnvironmentStrings(p_strEnvironment)
	If l_strTemp = p_strEnvironment Then
		l_strTemp = p_strDefault
	End If
	ExpandPath = l_strTemp
End Function